home *** CD-ROM | disk | FTP | other *** search
/ PC World Komputer 2010 April / PCWorld0410.iso / hity wydania / Ubuntu 9.10 PL / karmelkowy-koliberek-desktop-9.10-i386-PL.iso / casper / filesystem.squashfs / usr / bin / cpan2dist < prev    next >
Text File  |  2009-10-01  |  22KB  |  675 lines
  1. #!/usr/bin/perl
  2.     eval 'exec /usr/bin/perl -S $0 ${1+"$@"}'
  3.     if $running_under_some_shell;
  4. #!/usr/bin/perl -w
  5. use strict;
  6. use CPANPLUS::Backend;
  7. use CPANPLUS::Dist;
  8. use CPANPLUS::Internals::Constants;
  9. use Data::Dumper;
  10. use Getopt::Long;
  11. use File::Spec;
  12. use File::Temp                  qw|tempfile|;
  13. use File::Basename;
  14. use Locale::Maketext::Simple    Class => 'CPANPLUS', Style => 'gettext';
  15.  
  16. local $Data::Dumper::Indent = 1;
  17.  
  18. use constant PREREQ_SKIP_CLASS  => 'CPANPLUS::To::Dist::PREREQ_SKIP';
  19. use constant ALARM_CLASS        => 'CPANPLUS::To::Dist::ALARM';
  20.  
  21. ### print when you can
  22. $|++;
  23.  
  24. my $cb      = CPANPLUS::Backend->new
  25.                 or die loc("Could not create new CPANPLUS::Backend object");
  26. my $conf    = $cb->configure_object;
  27.  
  28. my %formats = map { $_ => $_ } CPANPLUS::Dist->dist_types;
  29.  
  30. my $opts    = {};
  31. GetOptions( $opts,
  32.             'format=s',             'archive',
  33.             'verbose!',             'force!',
  34.             'skiptest!',            'keepsource!',
  35.             'makefile!',            'buildprereq!',
  36.             'help',                 'flushcache',
  37.             'ban=s@',               'banlist=s@',
  38.             'ignore=s@',            'ignorelist=s@',
  39.             'defaults',             'modulelist=s@',
  40.             'logfile=s',            'timeout=s',
  41.             'dist-opts=s%',         'set-config=s%',
  42.             'default-banlist!',     'set-program=s%',
  43.             'default-ignorelist!',  'edit-metafile!',
  44.             'install!'
  45.         );
  46.         
  47. die usage() if exists $opts->{'help'};
  48.  
  49. ### parse options
  50. my $tarball     = $opts->{'archive'}    || 0;
  51. my $keep        = $opts->{'keepsource'} ? 1 : 0;
  52. my $prereqbuild = exists $opts->{'buildprereq'}
  53.                     ? $opts->{'buildprereq'}
  54.                     : 0;
  55. my $timeout     = exists $opts->{'timeout'} 
  56.                     ? $opts->{'timeout'} 
  57.                     : 300;
  58.  
  59. ### use default answers?
  60. $ENV{'PERL_MM_USE_DEFAULT'} = $opts->{'defaults'} ? 1 : 0;
  61.  
  62. my $format;
  63. ### if provided, we go with the command line option, fall back to conf setting
  64. {   $format      = $opts->{'format'}         || $conf->get_conf('dist_type');
  65.     $conf->set_conf( dist_type  => $format );
  66.  
  67.     ### is this a valid format??
  68.     die loc("Invalid format: " . ($format || "[NONE]") ) . usage() 
  69.         unless $formats{$format};
  70.  
  71.     ### any options to fix config entries
  72.     {   my $set_conf = $opts->{'set-config'} || {};
  73.         while( my($key,$val) = each %$set_conf ) {
  74.             $conf->set_conf( $key => $val );
  75.         }
  76.     }        
  77.  
  78.     ### any options to fix program entries
  79.     {   my $set_prog = $opts->{'set-program'} || {};
  80.         while( my($key,$val) = each %$set_prog ) {
  81.             $conf->set_program( $key => $val );
  82.         }
  83.     }        
  84.  
  85.     ### any other options passed
  86.     {   my %map = ( verbose     => 'verbose',
  87.                     force       => 'force',
  88.                     skiptest    => 'skiptest',
  89.                     makefile    => 'prefer_makefile'
  90.                 );
  91.                 
  92.         ### set config options from arguments        
  93.         while (my($key,$val) = each %map) {
  94.             my $bool = exists $opts->{$key} 
  95.                             ? $opts->{$key} 
  96.                             : $conf->get_conf($val);
  97.             $conf->set_conf( $val => $bool );
  98.         }    
  99.     }        
  100. }
  101.  
  102. my @modules = @ARGV;
  103. if( exists $opts->{'modulelist'} ) {
  104.     push @modules, map { parse_file( $_ ) } @{ $opts->{'modulelist'} }; 
  105. } 
  106.  
  107. die usage() unless @modules;
  108.  
  109. ### set up munge callback if requested
  110. {   if( $opts->{'edit-metafile'} ) {
  111.         my $editor = $conf->get_program('editor');
  112.         
  113.         if( $editor ) {
  114.     
  115.             ### register install callback ###
  116.             $cb->_register_callback(
  117.                 name    => 'munge_dist_metafile',
  118.                 code    => sub {
  119.                                 my $self = shift;
  120.                                 my $text = shift or return;
  121.                             
  122.                                 my($fh,$file) = tempfile( UNLINK => 1 );
  123.                                 
  124.                                 unless( print $fh $text ) {
  125.                                     warn "Could not print metafile information: $!";
  126.                                     return;
  127.                                 }
  128.                                 
  129.                                 close $fh;
  130.                                 
  131.                                 system( $editor => $file );
  132.                                 
  133.                                 my $cont = $cb->_get_file_contents( file => $file );
  134.                                 
  135.                                 return $cont;
  136.                             },
  137.             );
  138.             
  139.         } else {
  140.             warn "No editor configured. Can not edit metafiles!\n";
  141.         }
  142.     }
  143. }
  144.  
  145. my $fh;
  146. LOGFILE: {
  147.     if( my $file = $opts->{logfile} ) {
  148.         open $fh, ">$file" or ( 
  149.             warn loc("Could not open '%1' for writing: %2", $file,$!),
  150.             last LOGFILE
  151.         );            
  152.         
  153.         warn "Logging to '$file'\n";
  154.         
  155.         *STDERR = $fh;
  156.         *STDOUT = $fh;
  157.     }
  158. }
  159.  
  160. ### reload indices if so desired
  161. $cb->reload_indices() if $opts->{'flushcache'};
  162.  
  163. {   my @ban      = exists $opts->{'ban'}  
  164.                             ? map { qr/$_/ } @{ $opts->{'ban'} }
  165.                             : ();
  166.  
  167.  
  168.     if( exists $opts->{'banlist'} ) {
  169.         push @ban, map { parse_file( $_, 1 ) } @{ $opts->{'banlist'} };
  170.     }
  171.     
  172.     push @ban,  map  { s/\s+//; $_ }
  173.                 map  { [split /\s*#\s*/]->[0] }
  174.                 grep { /#/ }
  175.                 map  { split /\n/ } _default_ban_list() 
  176.         if $opts->{'default-banlist'};
  177.     
  178.     ### use our prereq install callback 
  179.     $conf->set_conf( prereqs => PREREQ_ASK );
  180.     
  181.     ### register install callback ###
  182.     $cb->_register_callback(
  183.             name    => 'install_prerequisite',
  184.             code    => \&__ask_about_install,
  185.     );
  186.  
  187.     
  188.     ### check for ban patterns when handling prereqs
  189.     sub __ask_about_install {
  190.   
  191.         my $mod     = shift or return;
  192.         my $prereq  = shift or return;
  193.     
  194.     
  195.         ### die with an error object, so we can verify that
  196.         ### the die came from this location, and that it's an
  197.         ### 'acceptable' death
  198.         my $pat = ban_me( $prereq );
  199.         die bless sub { loc("Module '%1' requires '%2' to be installed " .
  200.                         "but found in your ban list (%3) -- skipping",
  201.                         $mod->module, $prereq->module, $pat ) 
  202.                   }, PREREQ_SKIP_CLASS if $pat;
  203.         return 1;
  204.     }    
  205.     
  206.     ### should we skip this module?
  207.     sub ban_me {
  208.         my $mod = shift;
  209.         
  210.         for my $pat ( @ban ) {
  211.             return $pat if $mod->module =~ /$pat/i;
  212.         }
  213.         return;
  214.     }
  215. }    
  216.  
  217. ### patterns to strip from prereq lists
  218. {   my @ignore      = exists $opts->{'ignore'}  
  219.                         ? map { qr/$_/ } @{ $opts->{'ignore'} }
  220.                         : ();
  221.  
  222.     if( exists $opts->{'ignorelist'} ) {
  223.         push @ignore, map { parse_file( $_, 1 ) } @{ $opts->{'ignorelist'} };
  224.     }
  225.  
  226.     push @ignore, map  { s/\s+//; $_ }
  227.                   map  { [split /\s*#\s*/]->[0] }
  228.                   grep { /#/ }
  229.                   map  { split /\n/ } _default_ignore_list() 
  230.         if $opts->{'default-ignorelist'};
  231.  
  232.     
  233.     ### register install callback ###
  234.     $cb->_register_callback(
  235.             name    => 'filter_prereqs',
  236.             code    => \&__filter_prereqs,
  237.     );
  238.  
  239.     sub __filter_prereqs {
  240.         my $cb      = shift;
  241.         my $href    = shift;
  242.         
  243.         for my $name ( keys %$href ) {
  244.             my $obj = $cb->parse_module( module => $name ) or (
  245.                 warn "Cannot make a module object out of ".
  246.                         "'$name' -- skipping\n",
  247.                 next );
  248.  
  249.             if( my $pat = ignore_me( $obj ) ) {
  250.                 warn loc("'%1' found in your ignore list (%2) ".
  251.                          "-- filtering it out\n", $name, $pat);
  252.  
  253.                 delete $href->{ $name };                         
  254.             }
  255.         }
  256.  
  257.         return $href;
  258.     }
  259.     
  260.     ### should we skip this module?
  261.     sub ignore_me {
  262.         my $mod = shift;
  263.         
  264.         for my $pat ( @ignore ) {
  265.             return $pat if $mod->module =~ /$pat/i;
  266.             return $pat if $mod->package_name =~ /$pat/i;
  267.         }
  268.         return;
  269.     }   
  270. }     
  271.  
  272.  
  273. my %done;
  274. for my $name (@modules) {
  275.  
  276.     my $obj;
  277.     
  278.     ### is it a tarball? then we get it locally and transform it
  279.     ### and it's dependencies into .debs
  280.     if( $tarball ) {
  281.         ### make sure we use an absolute path, so chdirs() dont
  282.         ### mess things up
  283.         $name = File::Spec->rel2abs( $name ); 
  284.  
  285.         ### ENOTARBALL?
  286.         unless( -e $name ) {
  287.             warn loc("Archive '$name' does not exist");
  288.             next;
  289.         }
  290.         
  291.         $obj = CPANPLUS::Module::Fake->new(
  292.                         module  => basename($name),
  293.                         path    => dirname($name),
  294.                         package => basename($name),
  295.                     );
  296.  
  297.         ### if it's a traditional CPAN package, we can tidy
  298.         ### up the module name some
  299.         $obj->module( $obj->package_name ) if $obj->package_name;
  300.  
  301.         ### get the version from the package name
  302.         $obj->version( $obj->package_version || 0 );
  303.  
  304.         ### set the location of the tarball
  305.         $obj->status->fetch($name);
  306.  
  307.     ### plain old cpan module?    
  308.     } else {
  309.  
  310.         ### find the corresponding module object ###
  311.         $obj = $cb->parse_module( module => $name ) or (
  312.                 warn "Cannot make a module object out of ".
  313.                         "'$name' -- skipping\n",
  314.                 next );
  315.     }
  316.  
  317.     ### you banned it?
  318.     if( my $pat = ban_me( $obj ) ) {
  319.         warn loc("'%1' found in your ban list (%2) -- skipping\n",
  320.                     $obj->module, $pat );
  321.         next;
  322.     }        
  323.     
  324.     ### or just ignored it? 
  325.     if( my $pat = ignore_me( $obj ) ) {
  326.         warn loc("'%1' found in your ignore list (%2) -- skipping\n",
  327.                     $obj->module, $pat );
  328.         next;
  329.     }        
  330.     
  331.  
  332.     my $target  = $opts->{'install'} ? 'install' : 'create';
  333.     my $dist    = eval { 
  334.                     local $SIG{ALRM} = sub { die bless {}, ALARM_CLASS }
  335.                         if $timeout;
  336.                         
  337.                     alarm $timeout || 0;
  338.  
  339.                     my $dist_opts = $opts->{'dist-opts'} || {};
  340.  
  341.                     my $rv = $obj->install(   
  342.                             prereq_target   => $target,
  343.                             target          => $target,
  344.                             keep_source     => $keep,
  345.                             prereq_build    => $prereqbuild,
  346.  
  347.                             ### any passed arbitrary options
  348.                             %$dist_opts,
  349.                     );
  350.                     
  351.                     alarm 0; 
  352.  
  353.                     $rv;
  354.                 }; 
  355.                 
  356.     ### set here again, in case the install dies
  357.     alarm 0;
  358.  
  359.     ### install failed due to a 'die' in our prereq skipper?
  360.     if( $@ and ref $@ and $@->isa( PREREQ_SKIP_CLASS ) ) {
  361.         warn loc("Dist creation of '%1' skipped: '%2'", 
  362.                     $obj->module, $@->() );
  363.         next;
  364.  
  365.     } elsif ( $@ and ref $@ and $@->isa( ALARM_CLASS ) ) {
  366.         warn loc("\nDist creation of '%1' skipped, build time exceeded: ".
  367.                  "%2 seconds\n", $obj->module, $timeout );
  368.         next;                    
  369.  
  370.     ### died for some other reason? just report and skip
  371.     } elsif ( $@ ) {
  372.         warn loc("Dist creation of '%1' failed: '%2'",
  373.                     $obj->module, $@ );
  374.         next;
  375.     }        
  376.  
  377.     ### we didn't get a dist object back?
  378.     unless ($dist and $obj->status->dist) {
  379.         warn loc("Unable to create '%1' dist of '%2'", $format, $obj->module);
  380.         next
  381.     }
  382.  
  383.     print "Created '$format' distribution for ", $obj->module,
  384.                 " to:\n\t", $obj->status->dist->status->dist, "\n";
  385. }
  386.  
  387.  
  388. sub parse_file {
  389.     my $file    = shift or return;
  390.     my $qr      = shift() ? 1 : 0;
  391.  
  392.     my $fh = OPEN_FILE->( $file ) or return;
  393.  
  394.     my @rv;
  395.     while( <$fh> ) {
  396.         chomp;
  397.         next if /^#/;                   # skip comments
  398.         next unless /\S/;               # skip empty lines
  399.         s/^(\S+).*/$1/;                 # skip extra info
  400.         push @rv, $qr ? qr/$_/ : $_;    # add pattern to the list
  401.     }
  402.    
  403.     return @rv;
  404. }
  405.  
  406. =head1 NAME
  407.  
  408. cpan2dist - The CPANPLUS distribution creator
  409.  
  410. =head1 DESCRIPTION
  411.  
  412. This script will create distributions of C<CPAN> modules of the format
  413. you specify, including its prerequisites. These packages can then be
  414. installed using the corresponding package manager for the format.
  415.  
  416. Note, you can also do this interactively from the default shell,
  417. C<CPANPLUS::Shell::Default>. See the C<CPANPLUS::Dist> documentation,
  418. as well as the documentation of your format of choice for any format
  419. specific documentation.
  420.  
  421. =head1 USAGE
  422.  
  423. =cut
  424.  
  425. sub usage {
  426.     my $me      = basename($0);
  427.     my $formats = join "\n", map { "\t\t$_" } sort keys %formats;
  428.  
  429.     my $usage = << '=cut';
  430. =pod
  431.  
  432.  Usage: cpan2dist [--format FMT] [OPTS] Mod::Name [Mod::Name, ...]
  433.         cpan2dist [--format FMT] [OPTS] --modulelist /tmp/mods.list
  434.         cpan2dist [--format FMT] [OPTS] --archive /tmp/dist [/tmp/dist2] 
  435.  
  436.     Will create a distribution of type FMT of the modules
  437.     specified on the command line, and all their prerequisites.
  438.     
  439.     Can also create a distribution of type FMT from a local
  440.     archive and all it's prerequisites
  441.  
  442. =cut
  443.  
  444.     $usage .= qq[
  445.     Possible formats are:
  446. $formats
  447.  
  448.     You can install more formats from CPAN!
  449.     \n];
  450.     
  451.     $usage .= << '=cut';
  452. =pod
  453.     
  454. Options:
  455.  
  456.     ### take no argument:
  457.     --help          Show this help message
  458.     --install       Install this package (and any prerequisites you built)
  459.                     after building it. 
  460.     --skiptest      Skip tests. Can be negated using --noskiptest
  461.     --force         Force operation. Can be negated using --noforce
  462.     --verbose       Be verbose. Can be negated using --noverbose
  463.     --keepsource    Keep sources after building distribution. Can be
  464.                     negated by --nokeepsource. May not be supported 
  465.                     by all formats
  466.     --makefile      Prefer Makefile.PL over Build.PL. Can be negated
  467.                     using --nomakefile. Defaults to your config setting
  468.     --buildprereq   Build packages of any prerequisites, even if they are
  469.                     already uptodate on the local system. Can be negated
  470.                     using --nobuildprereq. Defaults to false.
  471.     --archive       Indicate that all modules listed are actually archives
  472.     --flushcache    Update CPANPLUS' cache before commencing any operation
  473.     --defaults      Instruct ExtUtils::MakeMaker and Module::Build to use
  474.                     default answers during 'perl Makefile.PL' or 'perl
  475.                     Build.PL' calls where possible
  476.     --edit-metafile Edit the distributions metafile(s) before the distribution
  477.                     is built. Requires a configured editor.
  478.  
  479.     ### take argument:
  480.     --format      Installer format to use (defaults to config setting)
  481.     --ban         Patterns of module names to skip during installation,
  482.                   case-insensitive (affects prerequisites too)
  483.                   May be given multiple times
  484.     --banlist     File containing patterns that could be given to --ban
  485.                   Are appended to the ban list built up by --ban
  486.                   May be given multiple times.
  487.     --ignore      Patterns of modules to exclude from prereq list. Useful
  488.                   for when a prereq listed by a CPAN module is resolved 
  489.                   in another way than from its corresponding CPAN package
  490.                   (Match is done on both module name, and package name of
  491.                   the package the module is in, case-insensitive)
  492.     --ignorelist  File containing patterns that may be given to --ignore.
  493.                   Are appended to the ban list built up by --ignore.
  494.                   May be given multiple times.
  495.     --modulelist  File containing a list of modules that should be built.
  496.                   Are appended to the list of command line modules.
  497.                   May be given multiple times.
  498.     --logfile     File to log all output to. By default, all output goes
  499.                   to the console.
  500.     --timeout     The allowed time for buliding a distribution before
  501.                   aborting. This is useful to terminate any build that 
  502.                   hang or happen to be interactive despite being told not 
  503.                   to be. Defaults to 300 seconds. To turn off, you can 
  504.                   set it to 0.
  505.     --set-config  Change any options as specified in your config for this
  506.                   invocation only. See CPANPLUS::Config for a list of 
  507.                   supported options.
  508.     --set-program Change any programs as specified in your config for this
  509.                   invocation only. See CPANPLUS::Config for a list of 
  510.                   supported programs.
  511.     --dist-opts   Arbitrary options passed along to the chosen installer
  512.                   format's prepare()/create() routine. Please see the
  513.                   documentation of the installer of your choice for 
  514.                   options it accepts.
  515.  
  516.     ### builtin lists
  517.     --default-banlist    Use our builtin banlist. Works just like --ban
  518.                          and --banlist, but with pre-set lists. See the
  519.                          "Builtin Lists" section for details.
  520.     --default-ignorelist Use our builtin ignorelist. Works just like 
  521.                          --ignore and --ignorelist but with pre-set lists. 
  522.                          See the "Builtin Lists" section for details.
  523.  
  524. Examples:
  525.  
  526.     ### build a debian package of DBI and it's prerequisites, 
  527.     ### don't bother running tests
  528.     cpan2dist --format CPANPLUS::Dist::Deb --buildprereq --skiptest DBI
  529.     
  530.     ### build a debian package of DBI and it's prerequisites and install them
  531.     cpan2dist --format CPANPLUS::Dist::Deb --buildprereq --install DBI
  532.     
  533.     ### Build a package, whose format is determined by your config, of 
  534.     ### the local tarball, reloading cpanplus' indices first and using
  535.     ### the tarballs Makefile.PL if it has one.
  536.     cpan2dist --makefile --flushcache --archive /path/to/Cwd-1.0.tgz
  537.     
  538.     ### build a package from Net::FTP, but dont build any packages or
  539.     ### dependencies whose name match 'Foo', 'Bar' or any of the 
  540.     ### patterns mentioned in /tmp/ban
  541.     cpan2dist --ban Foo --ban Bar --banlist /tmp/ban Net::FTP
  542.     
  543.     ### build a package from Net::FTP, but ignore it's listed dependency
  544.     ### on IO::Socket, as it's shipped per default with the OS we're on
  545.     cpan2dist --ignore IO::Socket Net::FTP
  546.     
  547.     ### building all modules listed, plus their prerequisites
  548.     cpan2dist --ignorelist /tmp/modules.ignore --banlist /tmp/modules.ban 
  549.       --modulelist /tmp/modules.list --buildprereq --flushcache 
  550.       --makefile --defaults
  551.     
  552.     ### pass arbitrary options to the format's prepare()/create() routine
  553.     cpan2dist --dist-opts deb_version=3 --dist-opts prefix=corp
  554.  
  555. =cut
  556.     
  557.     $usage .= qq[
  558. Builtin Lists:
  559.  
  560.     Ignore list:] . _default_ignore_list() . qq[
  561.     Ban list:] .    _default_ban_list();
  562.     
  563.     ### strip the pod directives
  564.     $usage =~ s/=pod\n//g;
  565.     
  566.     return $usage;
  567. }
  568.  
  569. =pod
  570.  
  571. =head1 Built-In Filter Lists
  572.  
  573. Some modules you'd rather not package. Some because they
  574. are part of core-perl and you dont want a new package.
  575. Some because they won't build on your system. Some because
  576. your package manager of choice already packages them for you.
  577.  
  578. There may be a myriad of reasons. You can use the C<--ignore>
  579. and C<--ban> options for this, but we provide some built-in
  580. lists that catch common cases. You can use these built-in lists
  581. if you like, or supply your own if need be.
  582.  
  583. =head2 Built-In Ignore List
  584.  
  585. =pod 
  586.  
  587. You can use this list of regexes to ignore modules matching
  588. to be listed as prerequisites of a package. Particulaly useful
  589. if they are bundled with core-perl anyway and they have known
  590. issues building.
  591.  
  592. Toggle it by supplying the C<--default-ignorelist> option.
  593.  
  594. =cut
  595.  
  596. sub _default_ignore_list {
  597.  
  598.     my $list = << '=cut';
  599. =pod
  600.  
  601.     ^IO$                    # Provided with core anyway
  602.     ^Cwd$                   # Provided with core anyway
  603.     ^File::Spec             # Provided with core anyway
  604.     ^Config$                # Perl's own config, not shipped separately
  605.     ^ExtUtils::MakeMaker$   # Shipped with perl, recent versions 
  606.                             # have bug 14721 (see rt.cpan.org)
  607.     ^ExtUtils::Install$     # Part of of EU::MM, same reason    
  608.  
  609. =cut
  610.  
  611.     return $list;
  612. }
  613.  
  614. =head2 Built-In Ban list
  615.  
  616. You can use this list of regexes to disable building of these
  617. modules altogether.
  618.  
  619. Toggle it by supplying the C<--default-banlist> option.
  620.  
  621. =cut
  622.  
  623. sub _default_ban_list {
  624.  
  625.     my $list = << '=cut';
  626. =pod
  627.  
  628.     ^GD$                # Needs c libaries
  629.     ^Berk.*DB           # DB packages require specific options & linking
  630.     ^DBD::              # DBD drives require database files/headers
  631.     ^XML::              # XML modules usually require expat libraries
  632.     Apache              # These usually require apache libraries
  633.     SSL                 # These usually require SSL certificates & libs
  634.     Image::Magick       # Needs ImageMagick C libraries
  635.     Mail::ClamAV        # Needs ClamAV C Libraries
  636.     ^Verilog            # Needs Verilog C Libraries
  637.     ^Authen::PAM$       # Needs PAM C libraries & Headers
  638.  
  639. =cut
  640.  
  641.     return $list;
  642. }
  643.  
  644. __END__
  645.  
  646. =head1 SEE ALSO
  647.  
  648. L<CPANPLUS::Dist>, L<CPANPLUS::Module>, L<CPANPLUS::Shell::Default>,
  649. C<cpanp>
  650.  
  651. =head1 BUG REPORTS
  652.  
  653. Please report bugs or other issues to E<lt>bug-cpanplus@rt.cpan.org<gt>.
  654.  
  655. =head1 AUTHOR
  656.  
  657. This module by Jos Boumans E<lt>kane@cpan.orgE<gt>.
  658.  
  659. =head1 COPYRIGHT
  660.  
  661. The CPAN++ interface (of which this module is a part of) is copyright (c) 
  662. 2001 - 2007, Jos Boumans E<lt>kane@cpan.orgE<gt>. All rights reserved.
  663.  
  664. This library is free software; you may redistribute and/or modify it 
  665. under the same terms as Perl itself.
  666.  
  667. =cut
  668.  
  669. # Local variables:
  670. # c-indentation-style: bsd
  671. # c-basic-offset: 4
  672. # indent-tabs-mode: nil
  673. # End:
  674. # vim: expandtab shiftwidth=4:
  675.